Elder Scrolls Forum: Making A Companion. How?

This is actually fairly simple to do. Here is a sample script you might be able to work from, which is used by all the melee-type companions in my Mercenary Pack mod:

Code:

begin BAR_MP_MercScriptMelee

short Companion
short levelup
short c_level
short c_athletics
short c_strength
short c_willpower
short c_intelligence
short c_agility
short c_endurance
short c_luck
short c_health
short c_magicka
short c_fatigue
short c_longblade
short c_mediumarmor
short c_heavyarmor
short c_bluntweapon
short c_axe
short c_unarmored
short c_block
short c_sneak
short c_speed
short p_speed

float playerx
float playery
float playerz
float warptimer

set playerx to ( Player->GetPos x )
set playery to ( Player->GetPos y )
set playerz to ( Player->GetPos z )

if ( menumode == 1 )
	if ( GetPCSleep == 0 )
		return
	endif
endif

if ( GetPCSleep == 1 )
	set levelup to 1
endif

set p_speed to ( Player->GetSpeed )

;Warp to player - Improves following ability

if ( GetCurrentAiPackage == 3 )
	if ( GetWeaponDrawn == 1 )
		elseif ( GetSpellReadied == 1 )
		return
			elseif ( GetDistance Player > 800 )
			set warptimer to warptimer + GetSecondsPassed
				if ( warptimer > 8 )
				set warptimer to 0
				SetPos x playerx
				SetPos y playery
				SetPos z playerz
		endif
	endif
endif

;Levitation warping

if ( GetEffect, sEffectLevitate == 1 )
	if ( GetWeaponDrawn == 1 )
	elseif ( GetSpellReadied == 1 )
		return
	elseif ( GetEffect, sEffectLevitate == 1 )
		SetPos z playerz
	endif
endif

;Companion will automatically cast levitation or water walking
;whenever the player does, while companion is is follow mode.
;Will dispel waterwalking effect if player stops using same effect.

if ( GetCurrentAIPackage == 3 )
	if ( Player->GetEffect, sEffectLevitate == 1 )
		if ( GetEffect, sEffectLevitate == 0 )
			Cast, "_BAR_merc_levitate", Player
		endif
	endif
	if ( Player->GetEffect, sEffectWaterWalking == 1 )
		if ( GetEffect, sEffectWaterWalking == 0 )
			Cast, "_BAR_merc_waterwalk", Player
		endif
	endif
	if ( GetEffect, sEffectWaterWalking == 1 )
		if ( Player->GetEffect, sEffectWaterWalking == 0 )
			Cast, "_BAR_merc_dispel", Player
		endif
	endif
endif

;Make companion fall with player when player's means of levitation expires
;Based on an original idea by "The Other Felix" and developed by Grumpy.

if ( Player->GetEffect, sEffectLevitate == 0 )
	if ( GetEffect, sEffectLevitate == 1 )
		SetPos z playerz
	endif
endif

;This section causes the companion to automatically sneak or stop 
;sneaking whenever the player does.

if ( GetCurrentAiPackage == 3 )
	if ( Player->GetPCSneaking == 1 )
		ForceSneak
	elseif ( Player->GetPCSneaking == 0 )
		ClearForceSneak
	endif
endif

;Decrease speed to a more reasonable level for wander/wait mode.

if ( GetCurrentAIPackage == 0 )
	SetSpeed 40
endif

;Increase speed for follow mode to improve following ability.

if ( GetCurrentAIPackage == 3 )
	set c_speed to ( p_speed + 100 )
	SetSpeed, c_speed
endif

;Automatic healing code.  Mercenary will automatically heal him/herself
;if he/she drops below 50% health, if the mercenary has enough magicka
;to do so.

if ( GetMagicka > 30 )  ;Checks to be sure companion has enough magicka
	if ( GetHealthGetRatio <= 0.5)
		Cast, "_BAR_MP_healself", Player
	endif
endif

;Level-up section. Will execute when mercenary is first hired, and whenever
;the player sleeps.

if ( levelup == 1 )
	set c_level to ( Player->GetLevel )

;Set new values for the 6 main character attributes.
;Personality is ignored, as it is useless to an NPC.

	set c_strength to (60 + (c_level * 2))
	set c_willpower to (50 + (c_level * 1))
	set c_intelligence to (30 + (c_level * 1))
	set c_agility to (30 + (c_level * 1))
	set c_endurance to (50 + (c_level * 1))
	set c_luck to (40 + (c_level * 0.5))

;Set new values for relevant skills. Only those skills
;deemed important to the character are affected.

	set c_longblade to (40 + (c_level * 1))
	set c_axe to (30 + (c_level * 1))
	set c_bluntweapon to (30 + (c_level * 1))
	set c_mediumarmor to (45 + (c_level * 1.25))
	set c_heavyarmor to (40 + (c_level * 1.5))
	set c_unarmored to (20 + (c_level * 1))
	set c_block to (5 +(c_level * 1))
	set c_sneak to (5 + (c_level * 1.25))
	set c_athletics to (5 + (c_level *1.25))

;This section enforces the 100-point cap
;for all stats and skills affected by this script.

	if ( c_athletics > 100 )
		set c_athletics to 100
	endif
	if ( c_strength > 100 )
		set c_strength to 100
	endif
	if ( c_willpower > 100 )
		set c_willpower to 100
	endif
	if ( c_intelligence > 100 )
		set c_strength to 100
	endif
	if ( c_agility > 100 )
		set c_agility to 100
	endif
	if ( c_endurance > 100 )
		set c_endurance to 100
	endif
	if ( c_luck > 100 )
		set c_luck to 100
	endif
	if ( c_longblade > 100 )
		set c_longblade to 100
	endif
	if ( c_unarmored > 100 )
		set c_unarmored to 100
	endif
	if ( c_block > 100 )
		set c_block to 100
	endif
	if ( c_mediumarmor > 100 )
		set c_mediumarmor to 100
	endif
	if ( c_heavyarmor > 100 )
		set c_heavyarmor to 100
	endif
	if ( c_axe > 100 )
		set c_axe to 100
	endif
	if ( c_bluntweapon > 100 )
		set c_bluntweapon to 100
	endif
	if ( c_sneak > 100 )
		set c_sneak to 100
	endif

;Set health, magicka, and fatigue.

	set c_health to (55 + (c_level * 9))
	set c_magicka to (50 + (c_level * 2.25))
	set c_fatigue to (150 + (c_level * 11))

	SetAthletics, c_athletics
	SetStrength, c_strength
	SetAgility, c_agility
	SetIntelligence, c_intelligence
	SetWillpower, c_willpower
	SetEndurance, c_endurance
	SetLuck, c_luck
	SetLongblade, c_longblade
	SetUnarmored, c_unarmored
	SetBlock, c_block
	SetMediumarmor, c_mediumarmor
	SetHeavyarmor, c_heavyarmor
	SetBluntweapon, c_bluntweapon
	SetAxe, c_axe
	SetSneak, c_sneak
	SetHealth, c_health
	SetMagicka, c_magicka
	SetFatigue, c_fatigue

	set levelup to 0
endif

end

This will provide all the basic functionality you want, including companion share, warping, even a level-up system, and even automatic healing. Note that all the spell IDs would need to be changed based on those that you will have to make and give to the companion in order to use those features. Also, you can change the numbers in the leveling section of the script to suit your personal taste. Feel free to experiment (just don't save while testing).

As for the dialog, that is probably most time-consuming part. I highly recommend that you take a look at the dialog for an existing companion mod, to see how it's done.

Hope this helps.

--------------------
My Morrowind Mods site and forums

Latest Release: Mercenary Pack Add-On 2: Guards

Post Extras:

short Companion
short c_levelup
short AIPackage

float playerx
float playery
float playerz
float warptimer

float mhealth
float chealth
float P_mhealth
float P_chealth
float p_speed
float c_speed

short c_level
short c_athletics
short c_strength
short c_willpower
short c_intelligence
short c_agility
short c_endurance
short c_luck
short c_health
short c_magicka
short c_fatigue

short c_shortblade
short c_unarmored
short c_block
short c_restoration
short c_spear
short c_lightarmor
short c_marksman
short c_security
short c_sneak
short DoNotUse
short c_mediumarmor
short c_heavyarmor
short c_longblade

float dispel_timer

short NoLore

if ( GetHealthGetRatio <= 0.5)
if ( GetEffect, sEffectRestoreHealth == 0 )
if ( GetMagicka > 30 ) ;Checks to be sure companion has enough magicka
Cast, "_zap_guard_healself", Player
elseif ( GetItemCount "p_restore_health_b" => 1 )
Equip "p_restore_health_b"
Playsound "Drink"
elseif ( GetItemCount "p_restore_health_c" => 1 )
Equip "p_restore_health_c"
Playsound "Drink"
elseif ( GetItemCount "p_restore_health_s" => 1 )
Equip "p_restore_health_s"
Playsound "Drink"
elseif ( GetItemCount "p_restore_health_q" => 1 )
Equip "p_restore_health_q"
Playsound "Drink"
elseif ( GetItemCount "p_restore_health_e" => 1 )
Equip "p_restore_health_e"
Playsound "Drink"
endif
endif
endif